[Sommaire] [Imprimer]

   1  @echo off
   2  if cmdextversion 2 goto :cmdok
   3  echo Sorry, this batch file requires a more recent version of Windows.
   4  goto :eof
   5  
   6  :cmdok
   7  setlocal
   8  setlocal enabledelayedexpansion
   9  
  10  call :searchpath xsltproc.exe
  11  if errorlevel 1 goto :eof
  12  set XSLTPROC=%RES%
  13  
  14  set NOOP=
  15  set DEBUG=
  16  set TRACE=
  17  :getopt
  18  if /I "%1" EQU "/n" set NOOP=1 && shift /1 && goto :getopt
  19  if /I "%1" EQU "-n" set NOOP=1 && shift /1 && goto :getopt
  20  if /I "%1" EQU "/d" set DEBUG=1 && shift /1 && goto :getopt
  21  if /I "%1" EQU "-d" set DEBUG=1 && shift /1 && goto :getopt
  22  if /I "%1" EQU "/t" set TRACE=1 && shift /1 && goto :getopt
  23  if /I "%1" EQU "-t" set TRACE=1 && shift /1 && goto :getopt
  24  
  25  if DEFINED NOOP (
  26    SET X=echo+
  27  ) ELSE (
  28    SET X=
  29  )
  30  
  31  set XSL_DEBUG=--param debug true^^^(^^^)
  32  set XSLTPROC_PARAMS=--nonet --novalid --xinclude
  33  set XSL_FILE=make.xsl
  34  if DEFINED DEBUG set XSLTPROC_PARAMS=%XSLTPROC_PARAMS% %XSL_DEBUG%
  35  if DEFINED TRACE set XSLTPROC_PARAMS=%XSLTPROC_PARAMS% --load-trace
  36  set TARGET_OK=
  37  set TARGETS=
  38  for /F "delims=:_ tokens=1,2" %%L in (%~sf0) DO (
  39      if "%%L" EQU "target" (
  40          set TARGETS=!TARGETS! %%M
  41          if /I "%%M" EQU "%1" set TARGET_OK=yes
  42      )
  43  )
  44  if "%TARGET_OK%"=="" goto :usage
  45  goto :target_%1
  46  :usage
  47  echo Usage: make [-n][-d][-t] target
  48  echo where target is one of %TARGETS%
  49  echo -n (or /n) Display but don't execute commands
  50  echo -d (or /d) Include XML comments in output files.
  51  echo -t (or /t) Show XML files as they are loaded
  52  goto :eof
  53  
  54  :target_dist
  55      %X%%XSLTPROC% %XSLTPROC_PARAMS% -o ..\common\kupu-widgeteer.html %XSL_FILE% dist.kupu 
  56      goto :eof
  57  
  58  :target_
  59  :target_all
  60      call :target_clean
  61      call :target_dist
  62      goto :eof
  63  
  64  :target_clean
  65      SET FILES=..\common\kupu-widgeteer.html
  66      for %%F in (%FILES%) DO (
  67          IF EXIST %%F ( %X%echo del %%F && %X%del %%F )
  68      )
  69      goto :eof
  70  
  71  :searchpath
  72      REM Search the path for the specified file. Also, for added
  73      REM friendliness, we extend the path with a few other 'potential'
  74      REM directories.
  75      SET PATHX=%PATH%;C:\libxslt;c:\Program Files\libxml\util
  76      set RES=%~s$PATHX:1
  77      if not errorlevel 1 goto :eof
  78      echo File %1 was not found in the PATH environment
  79      goto :eof